home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1997 May / EnigmA AMIGA RUN 18 (1997)(G.R. Edizioni)(IT)[!][issue 1997-05][EAR-CD II].iso / earcd / comm / misc / new8n1.lha / 8n1_020.s < prev    next >
Text File  |  1997-02-18  |  60KB  |  1,905 lines
  1. ********************************************************************************
  2. **                                          **
  3. **  Name       : 8n1_020.s                              **
  4. **  Copyright  : © Copyright 96-97                          **
  5. **  Author     : Iain Barclay                              **
  6. **  Created    : 18 Feb 97                              **
  7. **  Version    : 37.31                                  **
  8. **                                          **
  9. ********************************************************************************
  10.      ;
  11.      ;      SNMA specific options
  12.      ;
  13.      IFD      SNMA
  14.      ;
  15.      CPU      M68030
  16.      ;
  17.      SNMAOPT  Q,A,M,T,E-,P,R,B
  18.      ;
  19.      ELSE
  20.      ; I have phxopts define this symbol
  21.      IFD PHXASS
  22.      machine 68030
  23.      OPT !
  24.      ENDC
  25.      ENDC
  26.      ;
  27.      ;
  28. NEWCODE  SET      1
  29. SETDSR     SET      0
  30. NCOMM     SET      0
  31. STATS     SET      0
  32.      ;
  33.      ;
  34.      ;
  35.      SECTION  text,CODE
  36.      ;
  37.      ;
  38.      ;
  39. DEVICES_SERIAL_I_OBSOLETE  EQU        1
  40.      ;
  41.      ;
  42.      ;
  43.      INCLUDE  "exec/lists.i"
  44.      INCLUDE  "exec/memory.i"
  45.      INCLUDE  "exec/resident.i"
  46.      INCLUDE  "exec/devices.i"
  47.      INCLUDE  "exec/execbase.i"
  48.      INCLUDE  "exec/io.i"
  49.      INCLUDE  "exec/ports.i"
  50.      INCLUDE  "exec/errors.i"
  51.      INCLUDE  "exec/initializers.i"
  52.      INCLUDE  "intuition/preferences.i"
  53.      INCLUDE  "devices/timer.i"
  54.      INCLUDE  "devices/serial.i"
  55.      INCLUDE  "hardware/custom.i"
  56.      INCLUDE  "hardware/cia.i"
  57.      INCLUDE  "hardware/intbits.i"
  58.      INCLUDE  "hardware/adkbits.i"
  59.      INCLUDE  "resources/misc.i"
  60.      INCLUDE  "exec/alerts.i"
  61.      INCLUDE  "exec/macros.i"
  62.      INCLUDE  "8n1.device_rev.i"
  63.      ;
  64.      ;      Define hardware references
  65.      ;
  66.      XREF      _custom
  67.      XREF      _intena,_intenar,_intreq,_intreqr
  68.      XREF      _ciab,_ciabpra
  69.      XREF      _serper,_serdat,_serdatr
  70.      XREF      _adkcon,_adkconr
  71.      ;
  72.      ;      Exec Functions
  73.      ;
  74.      XREF      _LVORemDevice,_LVOOpenDevice,_LVOCloseDevice
  75.      XREF      _LVOSupervisor
  76.      XREF      _LVOAllocMem,_LVOFreeMem,_LVOCopyMem
  77.      XREF      _LVOReplyMsg
  78.      XREF      _LVOSendIO,_LVOAbortIO
  79.      XREF      _LVODisable,_LVOEnable
  80.      XREF      _LVOFindName
  81.      XREF      _LVOOpenResource
  82.      XREF      _LVOAddIntServer,_LVORemIntServer
  83.      XREF      _LVOAlert
  84.      XREF      _LVOOpenLibrary,_LVOCloseLibrary
  85.      ;
  86.      ;      Misc Resource Functions
  87.      ;
  88.      XREF      _LVOAllocMiscResource,_LVOFreeMiscResource
  89.      ;
  90.      ;      Intuition Functions
  91.      ;
  92.      XREF      _LVOGetPrefs
  93.      ;
  94.      ;      Mask used to get rid of the printer bits.
  95.      ;
  96. PRTMASK  EQU      (CIAF_PRTRPOUT|CIAF_PRTRBUSY)
  97.      ;
  98.      ;      Autovector offsets
  99.      ;
  100. LVL1VEC  EQU      (1-1)*4+$64
  101. LVL5VEC  EQU      (5-1)*4+$64
  102.      ;
  103.      ;  New Style device stuff (not the best way but it will have too do for now)
  104.      ;  If u don't have New Style stuff defined elsewhere remove these ;
  105. ;NSCMD_DEVICEQUERY   EQU $4000
  106. ; STRUCTURE  NSDEVICEQUERYRESULT,0
  107. ;    ULONG   DEVQUERYFORMAT
  108. ;    ULONG   SIZEAVAILABLE
  109. ;    UWORD   DEVICETYPE
  110. ;    UWORD   DEVICESUBTYPE
  111. ;    APTR    SUPPORTEDCOMMANDS
  112. ;    LABEL   NSDEVICEQUERYRESULT_SIZE
  113. ;NSDEVTYPE_SERIAL    EQU 11
  114.      ;
  115.      ;      Device base
  116.      ;
  117.      STRUCTURE Base8n1,LIB_SIZE
  118.      UBYTE      vb_SaveDDRA
  119.      UBYTE      vb_SavePRA
  120.      APTR      vb_MiscBase
  121.      APTR      vb_OldLevel1
  122.      APTR      vb_OldLevel5
  123.      ULONG      vb_SegList
  124.      ULONG      vb_DefBaud
  125.      ULONG      vb_DefRBufLen
  126.      ULONG      vb_CurRBuf
  127.      ULONG      vb_CurRBufLen
  128.      ULONG      vb_CurBaud
  129.      UBYTE      vb_SerFlags
  130.      UBYTE      vb_Initialized
  131.      LABEL      sizeof_Base8n1
  132.      ;
  133.      ;
  134.      ;
  135.     IFNE STATS
  136.      XREF      _KPrintF
  137.      XREF      KPrintF
  138.     ENDC
  139.      ;
  140.      ;
  141.      ;
  142. Start:
  143.      moveq      #-1,d0                  ; set return code
  144.      rts                          ; return
  145.      ;
  146.      ;      RamLib looks for this romtag
  147.      ;
  148. ROMTag     DC.W      RTC_MATCHWORD               ; RT_MATCHWORD
  149.      DC.L      ROMTag                  ; RT_MATCHTAG
  150.      DC.L      ENDTag                  ; RT_ENDSKIP
  151.      DC.B      RTF_AUTOINIT                  ; RT_FLAGS
  152.      DC.B      VERSION                  ; RT_VERSION
  153.      DC.B      NT_DEVICE                  ; RT_TYPE
  154.      DC.B      0                      ; RT_PRI
  155.      DC.L      Name                      ; RT_NAME
  156.      DC.L      IdString                  ; RT_IDSTRING
  157.      DC.L      Init                      ; RT_INIT
  158.      ;
  159.      ;      Perform device initialization
  160.      ;
  161.     cnop 0,4    ; align for 020+
  162. InitRoutine:
  163.      exg      d0,a0                   ; swap seglist and base
  164.      move.l   d0,vb_SegList(a0)              ; store seglist in base
  165.      move.l   a6,SysBase                  ; store in global storage
  166.      btst      #1,AttnFlags(a6)              ; test for 020+  #3 = 040, #4 = FPU, #6 = FPU040
  167.      beq.b      .ok
  168.      move.l   a1,-(sp)
  169.      move.l   d0,a0
  170.      move.l   d0,a1
  171.      moveq      #0,d0                   ; clear
  172.      move.w   LIB_NEGSIZE(a0),d0              ; calculate
  173.      suba.l   d0,a1                   ;   memory address
  174.      add.w      LIB_POSSIZE(a0),d0              ;     and size
  175.      jsr      _LVOFreeMem(a6)              ; free it
  176.      move.l   (sp)+,a1
  177.      moveq      #0,d0                   ; clear
  178.      bra.b      .rt
  179. .ok     exg      a0,d0                   ; swap them back
  180. .rt     rts                          ; return
  181.      ;
  182.      ;
  183.      ;
  184.     cnop 0,4 ; align for 020+
  185. dev_Open:   ; (a1 iorequest, a5 will be Base8n1, a6 sysbase )
  186.      move.l   a5,-(sp)                  ; save registers
  187.      movea.l  a6,a5                   ; save base
  188.      movea.l  SysBase(pc),a6              ; get ExecBase
  189.      ;
  190.      cmp.w      #IOEXTSER_SIZE,MN_LENGTH(a1)          ; IORequest size >= IOEXTSER_SIZE
  191.      bcs      50$                      ; nope, finish
  192.      ;
  193.      tst.l      d0                      ; unit 0 specified?
  194.      bne      50$                      ; nope, error (who cares?)
  195.      ;
  196.      tst.w      LIB_OPENCNT(a5)              ; currently open?
  197.      bne      10$                      ; yep, go process
  198.      ;
  199.      move.b   IO_SERFLAGS(a1),vb_SerFlags(a5)     ; save flags
  200.      ;
  201.      tst.b      vb_Initialized(a5)              ; already initialized?
  202.      bne      40$                      ; yep, skip initialization
  203.      ;
  204.      move.l   a1,-(sp)                  ; save register
  205.      ;
  206.      lea.l      miscresource(pc),a1              ; ptr to resource name
  207.      jsr      _LVOOpenResource(a6)              ; go open it
  208.      move.l   d0,vb_MiscBase(a5)              ; save base
  209.      ;
  210.      moveq      #MR_SERIALPORT,d0              ; set unit number
  211.      bsr      allocResource               ; go allocate it
  212.      tst.l      d0                      ; did we get it?
  213.      bne.b      20$                      ; nope, error
  214.      ;
  215.      moveq      #MR_SERIALBITS,d0              ; set unit number
  216.      bsr      allocResource               ; go allocate it
  217.      tst.l      d0                      ; did we get it?
  218.      bne.b      5$                      ; nope, error
  219.      ;
  220.      ;      Get system preferences
  221.      ;
  222.      move.l   a1,-(sp)                  ; save registers
  223.      ;
  224.      lea.l      intuitlib(pc),a1              ; ptr to library name
  225.      moveq      #0,d0                   ; can't use OldOpenLibrary as this will not be supported.
  226.      jsr      _LVOOpenLibrary(a6)              ; go open it (any version)
  227.      movea.l  d0,a6                   ; get intuition base
  228.      ;
  229.      move.l   #(pf_SerParShk+3)&$fffffffc,d0      ; size we need (aligned)
  230.      suba.l   d0,sp                   ; reserve space
  231.      ;
  232.      movea.l  sp,a0                   ; set data area ptr
  233.      jsr      _LVOGetPrefs(a6)              ; get preferences
  234.      ;
  235.      movea.l  a6,a1                   ; get intuition base
  236.      movea.l  SysBase(pc),a6              ; restore ExecBase
  237.      jsr      _LVOCloseLibrary(a6)              ; close it
  238.      ;
  239.      moveq      #$0f,d1                  ; set mask
  240.      and.b      pf_SerStopBuf(sp),d1              ; get bufsize index
  241.      addq.l   #8,d1                   ; calc shift value
  242.      moveq      #2,d0                   ; get 1<<1
  243.      lsl.l      d1,d0                   ; get default bufsize
  244.      move.l   d0,vb_DefRBufLen(a5)              ; and store
  245.      ;
  246.      moveq      #0,d1                   ; clear upper half
  247.      move.w   pf_BaudRate(sp),d1              ; get baud rate
  248.      move.w   .baudTable(pc,d1.l*2),d1          ; get baud rate
  249.      move.l   d1,vb_DefBaud(a5)              ; and store
  250.      ;
  251.      bsr      internalReset               ; go init baud and buffer
  252.      ;
  253.      lea.l      (pf_SerParShk+3)&$fffffffc(sp),sp   ; restore stack
  254.      movea.l  (sp)+,a1                  ; restore registers
  255.      tst.l      d0                      ; got 'em?
  256.      beq.b      30$                      ; yep, branch
  257.      ;
  258.      moveq      #MR_SERIALBITS,d0              ; set unit
  259.      movea.l  vb_MiscBase(a5),a6              ; get MiscBase
  260.      jsr      _LVOFreeMiscResource(a6)          ; release the resource
  261.      ;
  262. 5$     moveq      #MR_SERIALPORT,d0              ; set unit
  263.      movea.l  vb_MiscBase(a5),a6              ; get MiscBase
  264.      jsr      _LVOFreeMiscResource(a6)          ; release the resource
  265.      movea.l  SysBase(pc),a6              ; restore ExecBase
  266.      ;
  267. 20$     moveq      #SerErr_DevBusy,d0              ; set error status
  268.      bra      50$                      ; go return
  269.      ;
  270.      ;      Preferences baud lookup table
  271.      ;
  272.      cnop 0,4 ; align for 020+
  273. .baudTable:
  274.      dc.w      112,300,1200,2400,4800,9600,19200,31250,38400,57600,62400,64800
  275.      ;
  276.      cnop 0,4 ; align for 020+
  277. 30$     moveq      #0,d1                   ; clear flags
  278.      lea.l      timerReq(pc),a1              ; ptr to timer request
  279.      moveq      #UNIT_VBLANK,d0              ; set unit
  280.      lea.l      timerdevice(pc),a0              ; ptr to device name
  281.      jsr      _LVOOpenDevice(a6)              ; go open it
  282.      ;
  283.  
  284.      jsr      _LVODisable(a6)              ; disable interrupts
  285.      ;
  286.      lea.l      _ciab,a1                  ; get ptr to ciab
  287.      move.b   ciaddra(a1),d0
  288.      move.b   d0,vb_SaveDDRA(a5)              ; save DDR value
  289.      andi.b   #PRTMASK,d0                  ; make serial bits input
  290.      move.b   (a1),d1                  ; ciapra(a1)
  291.      ori.b      #CIAF_COMDTR|CIAF_COMRTS,d0          ; make DTR/RTS output
  292.      move.b   d1,vb_SavePRA(a5)              ; save PR value
  293.      andi.b   #CIAF_COMDTR|CIAF_COMRTS|PRTMASK,d0 ; turn on DTR/RTS
  294.      move.b   d0,ciaddra(a1)
  295.      andi.b   #CIAF_COMCTS|CIAF_COMDSR|PRTMASK,d1 ; make CTS/DSR input
  296.      move.b   d1,(a1)                  ; ciapra(a1)
  297.      ;
  298.      moveq      #INTB_PORTS,d0              ; get interrupt number
  299.      lea.l      VBInterrupt(pc),a1              ; get interrupt ptr
  300.      jsr      _LVOAddIntServer(a6)              ; add it to the list
  301.      ;
  302.      bsr      getVBR                  ; get vector base (in A0)
  303.      ;
  304.      move.l   LVL1VEC(a0),vb_OldLevel1(a5)          ; save original vector
  305.      lea.l      level1(pc),a1               ; get new vector ptr
  306.      move.l   a1,LVL1VEC(a0)              ; set new vector
  307.      ;
  308.      move.l   LVL5VEC(a0),vb_OldLevel5(a5)          ; save original vector
  309.      lea.l      level5(pc),a1               ; get new vector ptr
  310.      move.l   a1,LVL5VEC(a0)              ; set new vector
  311.      ;
  312.      lea.l      _custom,a1                  ; get ptr to custom chips
  313.      move.w   #INTF_RBF|INTF_TBE,intreq(a1)       ; clear pending interrupts
  314.      move.w   #INTF_SETCLR|INTF_RBF|INTF_TBE,intena(a1) ; enable RBF & TBE
  315.      ;
  316.      addq.b   #1,vb_Initialized(a5)           ; set flag
  317.      ;
  318.      jsr      _LVOEnable(a6)              ; enable interrupts
  319.      ;
  320.      movea.l  (sp)+,a1                  ; restore register
  321.      ;
  322.      bra.b      40$                      ; go exit
  323.      ;
  324.      cnop 0,4 ; align for 020+
  325. 10$     moveq      #SerErr_DevBusy,d0              ; preset error status
  326.      btst      #SERB_SHARED,vb_SerFlags(a5)          ; opened shared?
  327.      beq.b      50$                      ; nope, error
  328.      btst      #SERB_SHARED,IO_SERFLAGS(a1)          ; requesting shared?
  329.      beq.b      50$                      ; nope, error
  330.      ;
  331.      ;      Initialize I/O request
  332.      ;
  333. 40$     moveq      #8,d0                   ; get char size
  334.      move.b   d0,IO_READLEN(a1)              ; set read length
  335.      move.b   d0,IO_WRITELEN(a1)              ; set write length
  336.      moveq      #1,d0                   ; get stop bits
  337.      move.b   d0,IO_STOPBITS(a1)              ; set stop bits
  338.      move.b   IO_SERFLAGS(a1),d0
  339.      ori.b      #SERF_XDISABLED|SERF_RAD_BOOGIE|SERF_QUEUEDBRK|SERF_7WIRE,d0 ;flags
  340.      andi.b   #~(SERF_PARTY_ODD|SERF_PARTY_ON),d0 ; not used
  341.      move.b   d0,IO_SERFLAGS(a1)
  342.      move.l   vb_CurBaud(a5),IO_BAUD(a1)          ; set baud
  343.      move.l   vb_CurRBufLen(a5),IO_RBUFLEN(a1)    ; set read buffer length
  344.      ;
  345.      addq.w   #1,LIB_OPENCNT(a5)              ; incr open count
  346.      andi.b   #~(1<<LIBB_DELEXP),LIB_FLAGS(a5)    ; clear expunge bit
  347.      moveq      #0,d0                   ; no error
  348.      ;
  349. 50$     move.b   d0,IO_ERROR(a1)              ; store error code
  350.      movea.l  a5,a6                   ; restore base
  351.      move.l   (sp)+,a5                  ; restore registers
  352.      rts                          ; return
  353.      ;
  354.      ;      Attempt to allocate one of the serial resources.
  355.      ;
  356.      cnop 0,4 ; align for 020+
  357. allocResource:
  358.      move.l   a6,-(sp)                  ; save base pointer
  359.      move.l   d0,-(sp)                  ; save unit
  360.      lea.l      Name(pc),a1                  ; get lock name
  361.      move.l   vb_MiscBase(a5),a6              ; get MiscBase
  362.      jsr      _LVOAllocMiscResource(a6)          ; go allocate it
  363.      tst.l      d0                      ; did we get it?
  364.      beq.b      20$                      ; yep, branch
  365.      ;
  366.      ;      It's in use, so we try to locate the device using the string
  367.      ;      returned and attempt to remove it.
  368.      ;
  369.      movea.l  SysBase(pc),a6              ; get ExecBase
  370.      ;
  371.      movea.l  d0,a1                   ; get ptr to serial name
  372.      lea.l      DeviceList(a6),a0              ; get ptr to device list
  373.      jsr      _LVOFindName(a6)              ; go find it
  374.      tst.l      d0                      ; found?
  375.      beq.b      10$                      ; nope, branch
  376.      ;
  377.      movea.l  d0,a1                   ; xfer device ptr
  378.      jsr      _LVORemDevice(a6)              ; remove it
  379.      ;
  380.      ;      We then retry the allocate.
  381.      ;
  382. 10$     move.l   (sp),d0                  ; get unit
  383.      lea.l      Name(pc),a1                  ; get lock name
  384.      movea.l  vb_MiscBase(a5),a6              ; get MiscBase
  385.      jsr      _LVOAllocMiscResource(a6)          ; go allocate it
  386.      ;
  387. 20$     addq.l   #4,sp                   ; restore stack ptr
  388.      movea.l  (sp)+,a6                  ; restore base ptr
  389.      rts                          ; return
  390.      cnop 0,4 ; align for 020+
  391.      ;
  392.      ;      Set exception vectors
  393.      ;
  394.      cnop 0,4 ; align for 020+
  395. getVBR:
  396.      move.l   a5,-(sp)                  ; save registers
  397.      lea.l      20$(pc),a5                  ; ptr to routine
  398.      jsr      _LVOSupervisor(a6)              ; get into supervisor state
  399. 10$     movea.l  (sp)+,a5                  ; restore register
  400.      rts                          ; return
  401.      cnop      0,4
  402. 20$     movec.l  vbr,a0                  ; get vector base
  403.      rte                          ; return
  404.      ;
  405.      ;      Device Close routine
  406.      ;
  407.      cnop 0,4 ; align for 020+
  408. dev_Close:
  409.      ;
  410.      moveq      #-1,d0                  ; invalidate
  411.      move.l   d0,IO_DEVICE(a1)              ;   device
  412.      ;
  413.      tst.w      LIB_OPENCNT(a6)
  414.      beq      5$
  415.      subq.w   #1,LIB_OPENCNT(a6)              ; decr open count
  416.      bne      dev_Null                  ; still open? yep, branch
  417. 5$
  418.      ;
  419.      btst      #LIBB_DELEXP,LIB_FLAGS(a6)
  420.      beq      dev_Null
  421.      ;
  422.      ;      Device Expunge routine (also fall through from dev_Close)
  423.      ;
  424. dev_Expunge:
  425.      ori.b      #1<<LIBB_DELEXP,LIB_FLAGS(a6)       ; Set expunge flag
  426.      tst.w      LIB_OPENCNT(a6)              ; currently open?
  427.      bne      dev_Null                  ; yep, so just exit
  428.      ;
  429.      move.l   a5,-(sp)                  ; save registers
  430.      movea.l  a6,a5                   ; save base
  431.      movea.l  SysBase(pc),a6              ; get ExecBase
  432.      ;
  433.      move.l   a1,-(sp)                  ; save registers
  434.      ;
  435.      bsr.b      getVBR                  ; get vector base (in A0)
  436.      ;
  437.      moveq      #1,d0                   ; set not restored code
  438.      ;
  439.      lea.l      level1(pc),a1               ; get our vector ptr
  440.      cmpa.l   LVL1VEC(a0),a1              ; do they match?
  441.      bne      10$                      ; nope, can't restore
  442.      ;
  443.      lea.l      level5(pc),a1               ; get our vector ptr
  444.      cmpa.l   LVL5VEC(a0),a1              ; do they match?
  445.      bne      10$                      ; nope, can't restore
  446.      ;
  447.      jsr      _LVODisable(a6)              ; disable interrupts
  448.      ;
  449.      move.l   vb_OldLevel1(a5),LVL1VEC(a0)          ; restore original vector
  450.      move.l   vb_OldLevel5(a5),LVL5VEC(a0)          ; restore original vector
  451.      ;
  452.      moveq      #INTB_PORTS,d0              ; get interrupt number
  453.      lea.l      VBInterrupt(pc),a1              ; get interrupt ptr
  454.      jsr      _LVORemIntServer(a6)              ; remove it from the list
  455.      ;
  456.      lea.l      _custom,a0                  ; get custom base
  457.      move.w   #INTF_RBF|INTF_TBE,d0           ; indicate serial interrupts
  458.      move.w   d0,intena(a0)               ; disable interrupts
  459.      move.w   d0,intreq(a0)               ; clear pending interrupts
  460.      ;
  461.      bsr      freeBuf                  ; free allocated buffers
  462.      ;
  463.      lea.l      _ciab,a0                  ; get pointer to ciab
  464.      move.b   ciaddra(a0),d0              ; get DDR value
  465.      andi.b   #PRTMASK,d0                  ; save printer bits
  466.      ori.b      #~PRTMASK,d0                  ; set serial bits to output
  467.      move.b   d0,ciaddra(a0)              ; store value
  468.      ;
  469.      move.b   (a0),d0                  ; get PR value ( ciapra(a0) )
  470.      andi.b   #PRTMASK,d0                  ; mask out serial bits
  471.      move.b   vb_SavePRA(a5),d1              ; get saved value
  472.      andi.b   #~PRTMASK,d1                  ; mask out printer bits
  473.      or.b      d1,d0                   ; combine the two
  474.      move.b   d0,(a0)                  ; and store ( ciapra(a0) )
  475.      ;
  476.      move.b   ciaddra(a0),d0              ; get DDR value
  477.      andi.b   #PRTMASK,d0                  ; mask out serial bits
  478.      move.b   vb_SaveDDRA(a5),d1              ; get saved value
  479.      andi.b   #~PRTMASK,d1                  ; mask out printer bits
  480.      or.b      d1,d0                   ; combine the two
  481.      move.b   d0,ciaddra(a0)              ; and store
  482.      ;
  483.      lea.l      timerReq(pc),a1              ; get ptr to timer request
  484.      jsr      _LVOCloseDevice(a6)              ; go close it
  485.      ;
  486.      movea.l  vb_MiscBase(a5),a6              ; get MiscBase
  487.      moveq      #MR_SERIALBITS,d0              ; set unit
  488.      jsr      _LVOFreeMiscResource(a6)          ; release the resource
  489.      ;
  490.      moveq      #MR_SERIALPORT,d0              ; set unit
  491.      jsr      _LVOFreeMiscResource(a6)          ; release the resource
  492.      movea.l  SysBase(pc),a6              ; restore ExecBase
  493.      ;
  494.      jsr      _LVOEnable(a6)              ; enable interrupts
  495.      ;
  496.      subq.b   #1,vb_Initialized(a5)           ; clear flag
  497.      moveq      #0,d0                   ; free up everything
  498.      ;
  499. 10$     movea.l  (sp)+,a1                  ; restore registers
  500.      ;
  501.      movea.l  a5,a6                   ; restore base
  502.      movea.l  (sp)+,a5                  ; restore registers
  503.      ;
  504.      tst.l      d0                      ; freed?
  505.      bne.b      dev_Null                  ; nope, can't expunge, exit
  506.      ;
  507.      clr.b      vb_SerFlags(a6)              ; clear flags
  508.      ;
  509.      move.l   vb_SegList(a6),d0              ; get seglist ptr
  510.      move.l   d0,-(sp)                  ; save registers (save D0!)
  511.      ;
  512.      movea.l  a6,a1                   ; get base
  513.      ; This is the REMOVE macro
  514.      move.l   (a1)+,a0
  515.      move.l   (a1),a1                  ; LN_PRED
  516.      move.l   a0,(a1)
  517.      move.l   a1,LN_PRED(a0)
  518.      ;
  519.      movea.l  a6,a1                   ; get base
  520.      moveq      #0,d0                   ; clear work
  521.      move.w   LIB_NEGSIZE(a6),d0              ; calculate
  522.      suba.l   d0,a1                   ;   memory address
  523.      add.w      LIB_POSSIZE(a6),d0              ;     and size
  524.      move.l   a6,-(sp)                  ; save registers
  525.      movea.l  SysBase(pc),a6              ; get ExecBase
  526.      jsr      _LVOFreeMem(a6)              ; free it
  527.      ;
  528.      move.l   (sp)+,a6                  ; restore registers
  529.      move.l   (sp)+,d0                  ; restore registers
  530. exp_end  rts                          ; return (seglist in D0!)
  531.      ;
  532.      ;      Device "ExtFunc" routine
  533.      ;
  534.      cnop 0,4 ; align for 020+
  535. dev_Null:
  536.      moveq      #0,d0                   ; set return code
  537.      rts                          ; return
  538.      ;
  539.      ;
  540.      ;
  541.      ;
  542.      cnop 0,4 ; align for 020+
  543. cmdTable dc.w      cmd_Invalid-cmdTable              ; CMD_INVALID
  544.      dc.w      cmd_Reset-cmdTable              ; CMD_RESET
  545.      dc.w      cmd_Read-cmdTable              ; CMD_READ
  546.      dc.w      cmd_Write-cmdTable              ; CMD_WRITE
  547.      dc.w      cmd_Invalid-cmdTable              ; CMD_UPDATE
  548.      dc.w      cmd_Clear-cmdTable              ; CMD_CLEAR
  549.      dc.w      cmd_Invalid-cmdTable              ; CMD_STOP
  550.      dc.w      cmd_Invalid-cmdTable              ; CMD_START
  551.      dc.w      cmd_Flush-cmdTable              ; CMD_FLUSH
  552.      dc.w      sdcmd_Query-cmdTable              ; SDCMD_QUERY
  553.      dc.w      sdcmd_Break-cmdTable              ; SDCMD_BREAK
  554.      dc.w      sdcmd_SetParams-cmdTable          ; SDCMD_SETPARAMS
  555. endTable dc.w      nscmd_DeviceQuery-cmdTable          ; NSCMD_DEVICEQUERY
  556.      ;
  557.      ;      Device BeginIO routine
  558.      ;
  559.      cnop 0,4 ; align for 020+
  560. dev_BeginIO:
  561.      move.l   a5,-(sp)                  ; save register
  562.      movea.l  a6,a5                   ; save base
  563.      movea.l  SysBase(pc),a6              ; get ExecBase
  564.      ;
  565.      move.b   #NT_MESSAGE,LN_TYPE(a1)          ; set type
  566.      clr.b      IO_ERROR(a1)                  ; clear error
  567.      ;
  568.      andi.b   #~(IOSERF_QUEUED|IOSERF_ACTIVE),IO_FLAGS(a1) ; clear flags
  569.      ;
  570.      moveq      #0,d0
  571.      move.w   IO_COMMAND(a1),d0              ; get command
  572.      add.w      d0,d0                   ; multiply by 2
  573.      cmpi.w   #endTable-cmdTable,d0           ; in range?
  574.      bhi.b      25$                      ; nope, error
  575.      ;
  576. 5$     move.w   cmdTable(pc,d0.l),d0              ; get routine offset
  577.      jsr      cmdTable(pc,d0.l)              ; go do it
  578.      tst.l      d0                      ; I/O completed?
  579.      bne.b      19$                      ; nope, go return
  580.      ;
  581. 10$
  582.      btst      #IOB_QUICK,IO_FLAGS(a1)          ; need to reply?
  583.      bne.b      20$                      ; nope, branch
  584. 15$     jsr      _LVOReplyMsg(a6)              ; send it back
  585.      ;
  586. 19$     andi.b   #~(1<<IOB_QUICK),IO_FLAGS(a1)       ; clear quick bit
  587. 20$     movea.l  a5,a6                   ; restore base
  588.      movea.l  (sp)+,a5                  ; restore register
  589.      rts                          ; return
  590.      cnop 0,4 ; align for 020+
  591.      ;
  592. 25$     move.w   IO_COMMAND(a1),d0              ; get command
  593.      cmpi.w   #NSCMD_DEVICEQUERY,d0
  594.      bne.b      30$
  595.      moveq      #24,d0
  596.      bra.b      5$
  597.      cnop 0,4 ; align for 020+
  598.      ;
  599. 30$     move.b   #IOERR_NOCMD,IO_ERROR(a1)          ; invalid command
  600.      bra.b      10$                      ; branch
  601.      ;
  602.      ;      Device AbortIO routine
  603.      ;
  604.      cnop 0,4 ; align for 020+
  605. dev_AbortIO:
  606.      move.l   a5,-(sp)                  ; save registers
  607.      movea.l  a6,a5                   ; save base
  608.      movea.l  SysBase(pc),a6              ; get ExecBase
  609.      ;
  610.      jsr      _LVODisable(a6)              ; disable interrupts
  611.      ;
  612.      move.b   IO_FLAGS(a1),d1              ; get flags
  613.      btst      #IOSERB_QUEUED,d1              ; queued request?
  614.      bne.b      40$                      ; yep, branch
  615.      ;
  616.      btst      #IOSERB_ACTIVE,d1              ; active request?
  617.      beq.b      10$                      ; nope, just exit
  618.      ;
  619.      move.w   IO_COMMAND(a1),d0              ; get command
  620.      subq.w   #CMD_READ,d0                  ; was it a read?
  621.      beq.b      20$                      ; yep, go process
  622.      ;
  623.      subq.w   #CMD_WRITE-CMD_READ,d0          ; was it a write?
  624.      beq.b      30$                      ; yep, go process
  625.      ;
  626.      subq.w   #SDCMD_BREAK-CMD_WRITE,d0          ; was it a break?
  627.      beq.b      30$                      ; yep, go process
  628.      ;
  629.      ;      Fall through or enter from below
  630.      ;
  631. 10$     jsr      _LVOEnable(a6)              ; enable ints and return
  632. 15$     movea.l  a5,a6                   ; restore base
  633.      movea.l  (sp)+,a5                  ; restore registers
  634.      rts                          ; return
  635.      ;
  636.      ;      Abort an active read request
  637.      ;
  638. 20$     clr.l      cr_IOReq                  ; no longer active
  639.      bra.b      50$                      ; go set flags
  640.      ;
  641.      ;      Abort an active write request
  642.      ;
  643.      cnop 0,4 ; align for 020+
  644. 30$     clr.l      cw_Length                  ; no longer active
  645.      clr.l      cw_IOReq                  ; no longer active
  646.      move.l   cw_Buffer(pc),d0              ; get buffer ptr
  647.      sub.l      IO_DATA(a1),d0              ; calc number of bytes xfer'd
  648.      move.l   d0,IO_ACTUAL(a1)              ; store
  649.      ;
  650.      ;      Force a TBE interrupt to get the next write going.
  651.      ;
  652.      move.w   #INTF_SETCLR|INTF_TBE,_intreq       ; make TBE pending
  653.      bra.b      50$                      ; go set flags
  654.      ;
  655.      ;      Remove I/O from queue.
  656.      ;
  657.      cnop 0,4 ; align for 020+
  658. 40$     move.l   a1,-(sp)                  ; save ptr
  659.      ; This is the REMOVE macro
  660.      move.l   (a1)+,a0
  661.      move.l   (a1),a1                  ; LN_PRED
  662.      move.l   a0,(a1)
  663.      move.l   a1,LN_PRED(a0)
  664.      ;
  665.      movea.l  (sp)+,a1                  ; restore ptr
  666.      ;
  667.      ;      Set error and return I/O
  668.      ;
  669. 50$     move.b   #IOERR_ABORTED,IO_ERROR(a1)          ; set error code
  670.      move.b   IO_FLAGS(a1),d1              ; get flags
  671.      ori.b      #1<<IOSERB_ABORT,d1              ; set abort flag
  672.      andi.b   #~(IOSERF_QUEUED|IOSERF_ACTIVE),d1  ; clear flags
  673.      move.b   d1,IO_FLAGS(a1)              ; store flags
  674.      btst      #IOB_QUICK,d1               ; need to reply?
  675.      bne.b      10$                      ; nope, branch
  676.      jsr      _LVOReplyMsg(a6)              ; send it back
  677.      bra.b      10$                      ; branch to return
  678.      ;
  679.      ;      Abort all active/queued commands and reset internal state
  680.      ;
  681.      cnop 0,4 ; align for 020+
  682. cmd_Reset:
  683.      move.l   a1,-(sp)                  ; save I/O request
  684.      bsr.b      cmd_Flush                  ; go abort queued requests
  685.      ;
  686.      jsr      _LVODisable(a6)              ; disable interrupts
  687.      ;
  688.      ;      This must follow the DISABLE
  689.      ;
  690.      exg      a5,a6                   ; exchange base and ExecBase
  691.      ;
  692.      move.l   cr_IOReq(pc),d0              ; active read?
  693.      beq.b      10$                      ; nope, branch
  694.      movea.l  d0,a1                   ; get I/O request
  695.      bsr      dev_AbortIO                  ; go abort it
  696.      ;
  697.      ;
  698.      ;
  699. 10$     move.l   cw_IOReq(pc),d0              ; active write?
  700.      beq.b      20$                      ; nope, branch
  701.      movea.l  d0,a1                   ; get I/O request
  702.      bsr      dev_AbortIO                  ; go abort it
  703.      ;
  704. 20$     exg      a5,a6                   ; restore base and ExecBase
  705.      movea.l  (sp)+,a1                  ; restore I/O request
  706.      moveq      #8,d0                   ; get char size
  707.      move.b   d0,IO_READLEN(a1)              ; set read length
  708.      move.b   d0,IO_WRITELEN(a1)              ; set write length
  709.      moveq      #1,d0                   ; get stop bits
  710.      move.b   d0,IO_STOPBITS(a1)              ; set stop bits
  711.      move.l   vb_DefBaud(a5),IO_BAUD(a1)          ; set to default baud
  712.      move.l   vb_DefRBufLen(a5),IO_RBUFLEN(a1)    ; set to default buflen
  713.      bsr      internalReset               ; go set/verify parameters
  714.      move.b   d0,IO_ERROR(a1)              ; set error code
  715.      ;
  716.      ;      Set RC
  717.      ;
  718.      moveq      #0,d0                   ; I/O complete
  719.      jmp      _LVOEnable(a6)              ; enable interrupts
  720.                               ; return
  721.      ;
  722.      ;      Abort all "queued" requests, leaving all active alone.
  723.      ;
  724.      cnop 0,4 ; align for 020+
  725. cmd_Flush:
  726.      move.l   a2,-(sp)                  ; save registers
  727.      move.l   a1,-(sp)                  ; save registers
  728.      jsr      _LVODisable(a6)              ; disable interrupts
  729.      ;
  730.      ;      Abort all queued read requests.
  731.      ;
  732.      lea.l      readQ(pc),a2                  ; get ptr to read queue
  733.      bsr.b      20$                      ; branch to abort
  734.      ;
  735.      ;      Abort all queued write requests.
  736.      ;
  737.      lea.l      writeQ(pc),a2               ; get ptr to write queue
  738.      bsr.b      20$                      ; branch to abort
  739.      ;
  740.      ;      Enable, restore, and return to caller
  741.      ;
  742.      jsr      _LVOEnable(a6)              ; enable interrupts
  743.      move.l   (sp)+,a1                  ; restore registers
  744.      move.l   (sp)+,a2                  ; restore registers
  745.      ;
  746.      ;      Set RC and return
  747.      ;
  748.      moveq      #0,d0                   ; I/O complete
  749.      ;
  750.      ;      !!!NOTE!!!  In a mad attempt to save 2 bytes, this RTS is used
  751.      ;      by the subroutine below.  Why waste 'em?  B-)
  752.      ;
  753. 10$     rts                          ; return ( used below too!! )
  754.      ;
  755.      ;      Subroutine to remove and reply each I/O request.
  756.      ;
  757.      cnop 0,4 ; align for 020+
  758. 20$     movea.l  a2,a0                   ; get list ptr
  759.      ; This is the REMHEAD macro
  760. 25$     move.l   (a0),a1
  761.      move.l   (a1),d0
  762.      beq.b      25$
  763.      move.l   d0,(a0)
  764.      exg.l      d0,a1
  765.      move.l   a0,LN_PRED(a1)
  766.      ;
  767.      tst.l      d0                      ; end of list?
  768.      beq.b      10$                      ; yep, branch to return
  769.      ;
  770.      movea.l  d0,a1                   ; get I/O request
  771.      andi.b   #~(1<<IOSERB_QUEUED),IO_FLAGS(a1)   ; no longer queued
  772.      moveq      #IOERR_ABORTED,d0              ; indicate aborted
  773.      move.b   d0,IO_ERROR(a1)              ; store status
  774.      ;
  775.      jsr      _LVOReplyMsg(a6)              ; send it back
  776.      bra.b      20$                      ; continue with next
  777.      ;
  778.      ;      Process a CMD_READ request.
  779.      ;
  780.      cnop 0,4 ; align for 020+
  781. cmd_Read:
  782.      ;
  783.      ;      Zero length requests just get returned.
  784.      ;
  785.      clr.l      IO_ACTUAL(a1)               ; clear bytes read
  786.      move.l   IO_LENGTH(a1),d0              ; get length and test
  787.      beq.b      20$                      ; yep, leave
  788.      ;
  789.      ;      This can be used to circumvent a bug in NComm 3.0 which
  790.      ;      references the buffer even when there was nothing read.
  791.      ;
  792.     IFNE     NCOMM
  793.      move.l   IO_DATA(A1),a0              ; get data pointer
  794.      clr.b      (a0)                      ; clear first byte in buffer
  795.     ENDC
  796.      ;
  797.      ;      The disable counter works just like exec's TDNestCnt field.  It's
  798.      ;      initialized to -1.  After incrementing, if it is 0, then we
  799.      ;      can attempt to process this request immediately.  If it's > 0,
  800.      ;      then we're already disabled and we must queue this request.
  801.      ;
  802.      addq.b   #1,disableRead              ; incr disable count
  803.      bgt.b      50$                      ; >0, already disabled
  804.      ;
  805.      ;      If we're already processing an request, this one has to wait
  806.      ;      until that one is done, so go queue it.
  807.      ;
  808.      tst.l      cr_IOReq(pc)                  ; have an active request?
  809.      bne.b      50$                      ; yep, go queue this one
  810.      ;
  811.      ;      If we don't have enough bytes to satisfy this request then go
  812.      ;      queue it.
  813.      ;
  814.      cmp.l      i_InCnt(pc),d0              ; length > current bytes?
  815.      bgt.b      50$                      ; yep, go queue it
  816.      ;
  817.      ;      Setup fields and go copy the data
  818.      ;
  819.      move.l   IO_DATA(a1),cr_OutPtr           ; get/set output ptr
  820.      move.l   IO_LENGTH(a1),cr_Length          ; get/set output count
  821.      bsr      copyData                  ; go copy 'em
  822.      moveq      #0,d0                   ; I/O complete
  823.      ;
  824.      ;      We're done, so back off the disable counter.
  825.      ;
  826. 10$     subq.b   #1,disableRead              ; decr disable count
  827.      ;
  828.      ;      Return to caller
  829.      ;
  830. 20$     rts                          ; return
  831.      ;
  832.      ;      Just set flags and queue.  The read interrupt will handle it.
  833.      ;
  834. 50$     ori.b      #1<<IOSERB_QUEUED,IO_FLAGS(a1)    ; indicate queued
  835.      ;
  836.      ;      Add this request to the end.
  837.      ;
  838.      jsr      _LVODisable(a6)              ; disable interrupts
  839.      lea.l      readQ(pc),a0                  ; get pointer to read queue
  840.      ; This is the ADDTAIL macro
  841.      addq.l   #LH_TAIL,a0
  842.      move.l   LN_PRED(a0),d0
  843.      move.l   a1,LN_PRED(a0)
  844.      EXG      d0,a0
  845.      movem.l  d0/a0,(a1)
  846.      move.l   a1,(a0)
  847.      ;
  848.      jsr      _LVOEnable(a6)              ; enable interrupts
  849.      ;
  850.      ;      Indicate that this request was not handled immediatly.
  851.      ;
  852.      moveq      #1,d0                   ; I/O not complete
  853.      bra.b      10$                      ; branch to return
  854.      ;
  855.      ;      Process a CMD_WRITE request.
  856.      ;
  857.      cnop 0,4 ; align for 020+
  858. cmd_Write:
  859.      clr.l      IO_ACTUAL(a1)               ; clear bytes written
  860.      tst.l      IO_LENGTH(a1)               ; get length and test
  861.      bne.b      sdcmd_Break                  ; nope, proccess
  862.      rts
  863.      ;
  864.      ;      Entry point for Break command and fall through from cmd_Write.
  865.      ;
  866.      cnop 0,4 ; align for 020+
  867. sdcmd_Break:
  868.      ;
  869.      ;      Just set flags and queue. The TBE interrupt will handle it.
  870.      ;
  871.      ori.b      #1<<IOSERB_QUEUED,IO_FLAGS(a1)     ; indicate queued
  872.      ;
  873.      ;      Protect.
  874.      ;
  875.      jsr      _LVODisable(a6)             ; disable interrupts
  876.      ;
  877.      ;      Add request to end of queue.
  878.      ;
  879.      lea.l      writeQ(pc),a0               ; get queue list ptr
  880.      ; This is the ADDTAIL macro
  881.      addq.l   #LH_TAIL,a0
  882.      move.l   LN_PRED(a0),d0
  883.      move.l   a1,LN_PRED(a0)
  884.      EXG      d0,a0
  885.      movem.l  d0/a0,(a1)
  886.      move.l   a1,(a0)
  887.      ;
  888.      ;      If we have an active request, don't force interrupt.
  889.      ;
  890.      tst.l      cw_IOReq(pc)                  ; have an active request?
  891.      bne.b      10$                      ; yep, branch
  892.      ;
  893.      ;      Force a TBE interrupt to get the writes going.
  894.      ;
  895.      move.w   #INTF_SETCLR|INTF_TBE,_intreq       ; make TBE pending
  896.      ;
  897.      ;      Enable, set RC and return to caller.
  898.      ;
  899. 10$     moveq      #1,d0                   ; I/O not complete
  900.      jmp      _LVOEnable(a6)              ; enable interrupts
  901.                               ; return
  902.      ;
  903.      ;      Resets serial read buffer
  904.      ;
  905.      ;      Since this routine is called internally, it must NOT reference
  906.      ;      the I/O request.
  907.      ;
  908.      cnop 0,4 ; align for 020+
  909. cmd_Clear:
  910.      jsr      _LVODisable(a6)              ; disable interrupts
  911.      ;
  912.      ;      Load registers
  913.      ;
  914.      move.l   vb_CurRBuf(a5),d0              ; get internal buffer ptr
  915.      move.l   vb_CurRBufLen(a5),d1              ; and internal buffer len
  916.      lea.l      i_BufPtr(pc),a0              ; get ptr internal control
  917.      ;
  918.      ;      Initialize global buffer variables
  919.      ;
  920.      move.l   d0,(a0)+                  ; store buffer ptr
  921.      move.l   d0,(a0)+                  ; set current input ptr
  922.      move.l   d0,(a0)+                  ; set current output ptr
  923.      add.l      d1,d0                   ; add buffer length
  924.      move.l   d0,(a0)+                  ; store ptr to end of buffer
  925.      clr.l      (a0)+                   ; clear byte cnt
  926.      move.l   vb_CurBaud(a5),d0              ; get internal baud
  927.      lsr.l      #4,d0                   ; divide by 16
  928.      sub.l      d0,d1                   ; subtract from length
  929.      move.l   d1,(a0)                  ; set threshold
  930.      ;
  931.      ;      Enable, set RC and return.
  932.      ;
  933.      moveq      #0,d0                   ; I/O complete
  934.      jmp      _LVOEnable(a6)              ; enable interrupts
  935.                               ; return
  936.      ;
  937.      ;
  938.      ;
  939.      cnop 0,4 ; align for 020+
  940. cmd_Invalid
  941.      move.b   #IOERR_NOCMD,IO_ERROR(a1)          ; set bad status
  942.      moveq      #0,d0                   ; I/O complete
  943.      rts                          ; return
  944.      ;
  945.      ;      Returns number of bytes currently in internal buffer and
  946.      ;      current serial port status.
  947.      ;
  948.      ;      NOTE:  Not completely compatible with standard serial.device
  949.      ;      since it doesn't return the upper byte of IO_STATUS.
  950.      ;
  951.      cnop 0,4 ; align for 020+
  952. sdcmd_Query:
  953.      jsr      _LVODisable(a6)              ; disable interrupts
  954.      moveq      #0,d0                   ; clear d0
  955.      move.b   _ciabpra,d0                  ; get PR register
  956.      andi.b   #~PRTMASK,d0                  ; zap printer bits
  957.      ;
  958.      ;      To use this Set SETDSR to one.  This was done
  959.      ;      for a user whose DSR pin did not function.
  960.      ;
  961.     IFNE SETDSR
  962.      andi.b     #~(1<<CIAB_COMDSR),d0              ; set DSR
  963.     ENDC
  964.      ;
  965.      ;
  966.      ;
  967.      move.w   d0,IO_STATUS(a1)              ; store status
  968.      move.l   i_InCnt(pc),IO_ACTUAL(a1)          ; byte left in buffer
  969.      ;
  970.      ;      Enable, set RC and return.
  971.      ;
  972.      moveq      #0,d0                   ; I/O complete
  973.      jmp      _LVOEnable(a6)              ; enable interrupts
  974.                               ; return
  975.      ;
  976.      ;
  977.      ;
  978.      cnop 0,4 ; align for 020+
  979. sdcmd_SetParams:
  980.      ;
  981.      ;      Validate the read, write, and stop bit lengths.
  982.      ;
  983.      moveq      #8,d0                   ; get char length
  984.      cmp.b      IO_READLEN(a1),d0              ; 8 bit chars for read?
  985.      bne.b      40$                      ; nope, branch
  986.      cmp.b      IO_WRITELEN(a1),d0              ; 8 bit chars for write?
  987.      bne.b      40$                      ; nope, branch
  988.      moveq      #1,d0                   ; get stop bits
  989.      cmp.b      IO_STOPBITS(a1),d0              ; 1 stop bit?
  990.      bne.b      40$                      ; nope, branch
  991.      ;
  992.      ;      Get and validate the baud rate.
  993.      ;
  994.      move.l   IO_BAUD(a1),d1              ; get baud from I/O req
  995.      bne.b      20$                      ; specified?
  996.      move.l   vb_CurBaud(a5),d1              ; get current baud from base
  997.      bne.b      20$                      ; specified?
  998.      move.l   vb_DefBaud(a5),d1              ; get default baud from base
  999. 20$     cmpi.l   #110,d1                  ; too low?
  1000.      blt.b      40$                      ; error
  1001.      cmpi.l   #292000,d1                  ; too high?
  1002.      bgt.b      40$                      ; error
  1003.      ;
  1004.      ;      Get and validate the buffer length.
  1005.      ;
  1006.      move.l   IO_RBUFLEN(a1),d0              ; get buffer length
  1007.      bne.b      30$                      ; specified?
  1008.      move.l   vb_CurRBufLen(a5),d0              ; get current from base
  1009.      bne.b      30$                      ; specified?
  1010.      move.l   vb_DefRBufLen(a5),d0              ; get default from base
  1011.      ;
  1012. 30$     bsr.b      internalReset               ; go init baud and buffer
  1013. 35$     move.b   d0,IO_ERROR(a1)              ; set error code
  1014.      bne.b      39$
  1015.      ;
  1016.      ;      If the 7wire bit is not on, we will only use 3-wire protocol
  1017.      ;
  1018.      moveq      #0,d0                   ; clear flag
  1019.      btst      #SERB_7WIRE,IO_SERFLAGS(a1)          ; use 7wire handshaking?
  1020.      beq.b      36$                      ; nope, branch
  1021.      moveq      #1,d0                   ; set flag
  1022. 36$     move.b   d0,Handshake                  ; store flag
  1023.      ;
  1024.      ;      Set RC and return.
  1025.      ;
  1026. 39$     moveq      #0,d0                   ; I/O complete
  1027.      rts                          ; return
  1028.      ;
  1029.      ;      Invalid parm detected.
  1030.      ;
  1031. 40$     moveq      #SerErr_InvParam,d0              ; set error
  1032.      bra.b      35$                      ; go return
  1033.      ;
  1034.      ;  The NewStyleDevices Query command.
  1035.      ;
  1036.      cnop 0,4 ; align for 020+
  1037. nscmd_DeviceQuery:
  1038.      move.l   IO_DATA(a1),a0
  1039.      beq.b      10$
  1040.      moveq      #NSDEVICEQUERYRESULT_SIZE,d0
  1041.      move.l   d0,SIZEAVAILABLE(a0)
  1042.      move.l   d0,IO_ACTUAL(a1)
  1043.      move.w   #NSDEVTYPE_SERIAL,DEVICETYPE(a0)
  1044.      move.l   a1,-(sp)
  1045.      lea.l      cmdlist(pc),a1
  1046.      move.l   a1,SUPPORTEDCOMMANDS(a0)
  1047.      move.l   (sp)+,a1
  1048. 10$     moveq      #0,d0
  1049.      rts
  1050.      ;
  1051.      ;      Reset the buffer and baud rate
  1052.      ;
  1053.      ;      Registers:  D0 = Buffer length
  1054.      ;              D1 = Baud rate
  1055.      ;
  1056.      cnop 0,4 ; align for 020+
  1057. internalReset:
  1058.      ;
  1059.      ;      Disable interrupts.
  1060.      ;
  1061.      jsr      _LVODisable(a6)              ; disable interrupts
  1062.      ;
  1063.      ;      Save buffer length and go set serper.
  1064.      ;
  1065.      move.l   d0,-(sp)                  ; save D0
  1066.      move.l   d1,d0                   ; get baud rate
  1067.      ;
  1068.      ;      Set serial period register
  1069.      ;
  1070.      cmp.l      vb_CurBaud(a5),d0              ; current baud = new baud?
  1071.      beq.b      40$                      ; yep, just exit
  1072.      move.l   d0,vb_CurBaud(a5)              ; save new baud
  1073.      move.l   d0,d1                   ; save again
  1074.      lsl.l      #3,d0                   ; baud *= 8
  1075.      sub.l      d1,d0                   ; baud -= saved baud
  1076.      move.l   #25000000,d1                  ; get NTSC base
  1077.      cmpi.b   #50,PowerSupplyFrequency(a6)          ; PAL machine?
  1078.      bne.b      5$                      ; nope, branch
  1079.      move.l   #24772416,d1                  ; get PAL base
  1080. 5$     cmpi.l   #$FFFF,d0                  ; Divide
  1081.      ble.b      20$                      ;
  1082.      lsr.l      #5,d0                   ;
  1083.      divu.w   d0,d1                   ;
  1084.      andi.l   #$FFFF,d1                  ;
  1085.      lsr.l      #5,d1                   ;
  1086.      bra.b      30$                      ;
  1087.      cnop 0,4 ; align for 020+
  1088. 20$     divu.w   d0,d1                   ;
  1089. 30$     move.w   d1,_serper                  ; set period value
  1090. 40$
  1091.      move.l   (sp)+,d0                  ; restore D0
  1092.      ;
  1093.      ;      Determine if the buffer length is adequate for the selected CPS.
  1094.      ;      If not, use 64K for the length.
  1095.      ;
  1096.      move.l   vb_CurBaud(a5),d1              ; get current baud
  1097.      lsr.l      #$3,d1                  ; divide by 8
  1098.      cmp.l      d1,d0                   ; buflen > CPS
  1099.      bhi.b      10$                      ; yep, branch
  1100.      move.l   #65536,d0                  ; else use 64K
  1101.      ;
  1102.      ;      Allocate new internal buffer
  1103.      ;
  1104. 10$     cmp.l      vb_CurRBufLen(a5),d0              ; len same as previous?
  1105.      beq.b      11$                      ; yep, so no need to alloc
  1106.      move.l   d0,d1                   ; save length
  1107.      move.l   a1,-(sp)                  ; save registers
  1108.      move.l   d1,-(sp)                  ; save registers
  1109.      moveq      #MEMF_PUBLIC,d1              ; public memory
  1110.      jsr      _LVOAllocMem(a6)              ; go allocate it
  1111.      move.l   (sp)+,d1                  ; restore registers
  1112.      move.l   (sp)+,a1                  ; restore registers
  1113.      tst.l      d0                      ; did we get it?
  1114.      beq.b      21$                      ; if zero, error
  1115.      bsr.b      freeBuf                  ; go free previous buffer
  1116.      move.l   d0,vb_CurRBuf(a5)              ; store new ptr
  1117.      move.l   d1,vb_CurRBufLen(a5)              ; and length
  1118.      bsr      cmd_Clear                  ; go setup buffer
  1119. 11$     moveq      #0,d0                   ; success
  1120.      bra.b      22$                      ; return
  1121.      cnop 0,4 ; align for 020+
  1122. 21$     moveq      #SerErr_BufErr,d0              ; set error status
  1123. 22$
  1124.      ;
  1125.      ;      Enable and return to caller.
  1126.      ;
  1127.      jmp      _LVOEnable(a6)              ; enable interrupts / return (D0 has status)
  1128.      ;
  1129.      ;      Free internal buffer
  1130.      ;
  1131.      cnop 0,4 ; align for 020+
  1132. freeBuf:
  1133.      movem.l  d0-d1/a0-a1,-(sp)              ; save registers
  1134.      move.l   vb_CurRBuf(a5),d0              ; is one there?
  1135.      beq.b      10$                      ; no so branch
  1136.      movea.l  d0,a1                   ; get ptr
  1137.      move.l   vb_CurRBufLen(a5),d0              ; get length
  1138.      clr.l      vb_CurRBuf(a5)              ; clear
  1139.      clr.l      vb_CurRBufLen(a5)              ; clear
  1140.      jsr      _LVOFreeMem(a6)              ; free it
  1141. 10$     move.l   (sp)+,d0                  ; restore registers
  1142.      move.l   (sp)+,d1                  ; restore registers
  1143.      move.l   (sp)+,a0                  ; restore registers
  1144.      move.l   (sp)+,a1                  ; restore registers
  1145.      rts                          ; return
  1146.      ;
  1147.      ;      Checks CTS status and if clear generates a TBE interrupt or
  1148.      ;      requeues the timer request.
  1149.      ;
  1150.      ;      Entered from Exec using the MsgPort callback.
  1151.      ;
  1152.      ;      Input:   a6 = ExecBase
  1153.      ;      Output:  none
  1154.      ;
  1155.      ;      No need to preserve d0/d1/a0/a1
  1156.      ;
  1157.      cnop 0,4 ; align for 020+
  1158. timerRtn:
  1159.      lea.l      timerReq(pc),a1              ; get ptr to timer request
  1160.      ; This is the REMOVE macro
  1161.      move.l   (a1)+,a0
  1162.      move.l   (a1),a1                  ; LN_PRED
  1163.      move.l   a0,(a1)
  1164.      move.l   a1,LN_PRED(a0)
  1165.      ;
  1166.      ;      If we were breaking, reset adkcon.
  1167.      ;
  1168.      lea.l      _custom,a0                  ; get ptr to custom regs
  1169.      btst      #ADKB_UARTBRK&7,adkconr(a0)          ; were we breaking?
  1170.      beq.b      10$                      ; nope, skip reset
  1171.      ;
  1172.      move.w   #ADKF_UARTBRK,adkcon(a0)          ; stop breaking
  1173.      ;
  1174.      ;
  1175.      ;
  1176. 10$     tst.b      Handshake(pc)               ; are we handshaking?
  1177.      beq.b      20$                      ; nope, generate interrupt
  1178.      btst      #CIAB_COMCTS,_ciabpra           ; clear to send?
  1179.      beq.b      20$                      ; yep, go start writing
  1180.      ;
  1181.      lea.l      timerReq(pc),a1              ; get ptr to timer request
  1182.      move.l   #1000,IOTV_TIME+TV_MICRO(a1)          ; wait for .001 seconds
  1183.      jsr      _LVOSendIO(a6)              ; go queue it
  1184.      bra.b      30$                      ; branch to return
  1185.      ;
  1186.      ;      CTS is clear so generate TBE interrupt to restart writing
  1187.      ;
  1188.      cnop 0,4 ; align for 020+
  1189. 20$     move.w   #INTF_SETCLR|INTF_TBE,intreq(a0)    ; set TBE interrupt
  1190. 30$     rts                          ; return
  1191.      ;
  1192.      ;      Non serial interrupt
  1193.      ;
  1194.      ;  a0 - custom chips base
  1195.      ;  a1 - is_Data
  1196.      cnop 0,4 ; align for 020+
  1197. level1n:
  1198.      movem.l  d0-d1/a0-a1/a5-a6,-(sp)          ; save registers
  1199.      lea      _custom,a0                  ; get ptr to custom regs
  1200.      move.w   intenar(a0),d1              ; get enabled interrupts
  1201.      and.w      intreqr(a0),d1              ; and in requested interrupts
  1202.      movea.l  SysBase(pc),a6              ; get ExecBase
  1203.      ;
  1204.      btst      #INTB_DSKBLK,d1              ; Disk block done?
  1205.      beq.b      10$                      ; nope, branch
  1206.      ;
  1207.      movem.l  IVDSKBLK(a6),a1/a5              ; get data and code ptrs
  1208.      pea.l      20$(pc)                  ; push return address
  1209.      jmp      (a5)                      ; jump to routine
  1210.      ;
  1211. 10$     btst      #INTB_SOFTINT,d1              ; software interrupt?
  1212.      beq.b      20$                      ; nope, branch
  1213.      ;
  1214.      movem.l  IVSOFTINT(a6),a1/a5              ; get data and code ptrs
  1215.      jsr      (a5)                      ; jump to routine
  1216.      ;
  1217. 20$     move.l   (sp)+,d0                  ; restore registers
  1218.      move.l   (sp)+,d1                  ; restore registers
  1219.      move.l   (sp)+,a0                  ; restore registers
  1220.      move.l   (sp)+,a1                  ; restore registers
  1221.      move.l   (sp)+,a5                  ; restore registers
  1222.      move.l   (sp)+,a6                  ; restore registers
  1223.      rte                          ; return
  1224.      ;
  1225.      ;      Level 1 interrupt handler
  1226.      ;
  1227.      ;  a1 - is_Data
  1228.      ;
  1229.      cnop 0,4 ; align for 020+
  1230. level1:
  1231.      btst      #INTB_INTEN&7,_intenar          ; interrupts enabled?
  1232.      beq.b      35$                      ; nope, ignore
  1233.     IFEQ NEWCODE
  1234.      btst      #INTB_SOFTINT,_intreqr+1          ; software interrupt?
  1235.      bne.b      level1n                  ; nope, branch
  1236.     ENDC
  1237.      btst      #INTB_TBE,_intreqr+1              ; xmit buffer empty?
  1238.      beq.b      level1n                  ; nope, invoke old handler
  1239.      ;
  1240.      ;      Handle "Transmit Buffer Empty" interrupt (write)
  1241.      ;
  1242.      move.w   #INTF_TBE,_intreq              ; clear interrupt
  1243.      move.l   d0,-(sp)                  ; save D0 (faster than MOVEM)
  1244.      move.l   a0,-(sp)                  ; save A0 (faster than MOVEM)
  1245.      ;
  1246.      ;      If we're not handshaking, bypass it.
  1247.      ;
  1248. 10$     tst.b      Handshake(pc)               ; are we handshaking?
  1249.      beq.b      20$                      ; nope, skip CTS test
  1250.      btst      #CIAB_COMCTS,_ciabpra           ; clear to send?
  1251.      bne.b      40$                      ; nope, branch
  1252.      ;
  1253.      ;      If cw_Length goes negative here, we are either done with a
  1254.      ;      request or we were called as a result of a fake interrupt
  1255.      ;      to force us to get the next request going.
  1256.      ;
  1257. 20$     subq.l   #1,cw_Length                  ; decr write length
  1258.      blt.b      60$                      ; < zero, done, branch
  1259.      ;
  1260.      ;      Currently processing a request.
  1261.      ;
  1262.      movea.l  cw_Buffer(pc),a0              ; get buffer ptr
  1263.      move.w   #256,d0                  ; set stop bit
  1264.      move.b   (a0)+,d0                  ; get next byte
  1265.      move.l   a0,cw_Buffer                  ; store buffer ptr
  1266.      move.w   d0,_serdat                  ; store in serdat reg
  1267.      ;
  1268. 30$     movea.l  (sp)+,a0                  ; restore registers
  1269.      move.l   (sp)+,d0                  ; restore registers
  1270. 35$     rte                          ; return
  1271.      ;
  1272.      ;      Queue a timer request to recheck CTS status
  1273.      ;
  1274. 40$     movem.l  d1/a1/a6,-(sp)              ; save registers
  1275.      lea.l      timerReq(pc),a1              ; get ptr to timer request
  1276.      move.l   #1000,IOTV_TIME+TV_MICRO(a1)          ; wait for .001 seconds
  1277.      movea.l  SysBase(pc),a6              ; get ExecBase
  1278.      jsr      _LVOSendIO(a6)              ; queue the request
  1279.      move.l   (sp)+,d1                  ; restore registers
  1280.      move.l   (sp)+,a1                  ; restore registers
  1281.      move.l   (sp)+,a6                  ; restore registers
  1282.      bra.b      30$                      ; go return
  1283.      ;
  1284.      ;      There aren't anymore requests, so clear and exit
  1285.      ;
  1286.      cnop 0,4 ; align for 020+
  1287. 50$     clr.l      cw_Length-Start(a6)              ; clear length
  1288.      clr.l      cw_IOReq-Start(a6)              ; clear
  1289.      move.l   (sp)+,d1                  ; restore registers
  1290.      move.l   (sp)+,a1                  ; restore registers
  1291.      move.l   (sp)+,a6                  ; restore registers
  1292.      bra.b      30$                      ; go return
  1293.      ;
  1294.      ;      Write request completed
  1295.      ;
  1296.      cnop 0,4 ; align for 020+
  1297. 60$     movem.l  d1/a1/a6,-(sp)              ; save registers
  1298.      ;
  1299.      move.l   cw_IOReq(pc),d0              ; active I/O request?
  1300.      beq.b      70$                      ; nope, branch
  1301.      ;
  1302.      ;      Reply it and setup for next
  1303.      ;
  1304.      movea.l  d0,a1                   ; get I/O request
  1305.      andi.b   #~(1<<IOSERB_ACTIVE),IO_FLAGS(a1)   ; no longer active
  1306.      clr.b      IO_ERROR(a1)                  ; no error
  1307.      movea.l  SysBase(pc),a6              ; get ExecBase
  1308.      jsr      _LVOReplyMsg(a6)              ; return I/O request
  1309.      ;
  1310. 70$     lea.l      Start(pc),a6                  ; get section base
  1311.      ;
  1312.      lea.l      writeQ(pc),a1               ; get ptr to write queue
  1313.      move.l   (a1),a0                  ; get head of list
  1314.      move.l   (a0),d0                  ; get successor
  1315.      beq.b      50$                      ; end of list? yep, branch
  1316.      ;
  1317.      ;      Remove the node from the list
  1318.      ;
  1319.      move.l   d0,(a1)                  ; make new head
  1320.      exg.l      d0,a0                   ; swap nodes
  1321.      move.l   a1,LN_PRED(a0)              ; store predecessor
  1322.      ;
  1323.      move.l   d0,a1                   ; get I/O request
  1324.      ;
  1325.      ;      If it's a BREAK, then branch to process as such.
  1326.      ;
  1327.      cmpi.w   #SDCMD_BREAK,IO_COMMAND(a1)          ; BREAK command?
  1328.      beq.b      100$                      ; yep, branch
  1329.      ;
  1330.      ;      Check for absolute length
  1331.      ;
  1332.      move.l   IO_DATA(a1),a0              ; get data ptr
  1333.      moveq      #-1,d1                  ; get value
  1334.      move.l   IO_LENGTH(a1),d0              ; get length
  1335.      cmp.l      d1,d0                   ; length = -1?
  1336.      bne.b      90$                      ; nope, skip scan
  1337.      ;
  1338.      ;      Scan the data for null to calc the length
  1339.      ;
  1340.      move.l   a0,d1                   ; save data ptr
  1341. 80$     tst.b      (a0)+                   ; does it equal 0? (first byte)
  1342.      beq.b      81$                      ; yep, finish
  1343.      tst.b      (a0)+                   ; does it equal 0? (second byte)
  1344.      beq.b      81$                      ; yep, finish
  1345.      tst.b      (a0)+                   ; does it equal 0? (third byte)
  1346.      beq.b      81$                      ; yep, finish
  1347.      tst.b      (a0)+                   ; does it equal 0? (fourth byte)
  1348.      bne.b      80$                      ; nope, loop
  1349. 81$
  1350.      suba.l   d1,a0                   ; calc # of bytes
  1351.      move.l   a0,d0                   ; xfer
  1352.      movea.l  d1,a0                   ; get data ptr
  1353.      ;
  1354. 90$     move.l   d0,IO_ACTUAL(a1)              ; go ahead and set it
  1355.      move.b   IO_FLAGS(a1),d1
  1356.      andi.b   #~(1<<IOSERB_QUEUED),d1          ; no longer queued
  1357.      ori.b      #1<<IOSERB_ACTIVE,d1              ; make it active
  1358.      move.b   d1,IO_FLAGS(a1)
  1359.      move.l   d0,cw_Length-Start(a6)          ; store length
  1360.      move.l   a0,cw_Buffer-Start(a6)          ; store buffer ptr
  1361.      move.l   a1,cw_IOReq-Start(a6)           ; store I/O request ptr
  1362.      ;
  1363.      move.l   (sp)+,d1                  ; restore registers
  1364.      move.l   (sp)+,a1                  ; restore registers
  1365.      move.l   (sp)+,a6                  ; restore registers
  1366.      bra      10$                      ; go start request
  1367.      ;
  1368.      ;      Start the BREAK.
  1369.      ;
  1370.      cnop 0,4 ; align for 020+
  1371. 100$     move.b   IO_FLAGS(a1),d1
  1372.      andi.b   #~(1<<IOSERB_QUEUED),d1          ; no longer queued
  1373.      ori.b      #1<<IOSERB_ACTIVE,d1              ; make it active
  1374.      move.b   d1,IO_FLAGS(a1)
  1375.      clr.l      cw_Length-Start(a6)              ; clear length
  1376.      move.l   a1,cw_IOReq-Start(a6)           ; store I/O request ptr
  1377.      move.w   #ADKF_SETCLR|ADKF_UARTBRK,_adkcon   ; start break
  1378.      move.l   IO_BRKTIME(a1),d0              ; get break time
  1379.      lea.l      timerReq(pc),a1              ; get ptr to timer request
  1380.      move.l   d0,IOTV_TIME+TV_MICRO(a1)          ; set the timeout
  1381.      movea.l  SysBase(pc),a6              ; get ExecBase
  1382.      jsr      _LVOSendIO(a6)              ; queue the request
  1383.      move.l   (sp)+,d1                  ; restore registers
  1384.      move.l   (sp)+,a1                  ; restore registers
  1385.      move.l   (sp)+,a6                  ; restore registers
  1386.      bra      30$                      ; go exit
  1387.      ;
  1388.      ;      Non serial interrupt
  1389.      ;
  1390.      ;  a1 - custom chips base
  1391.      ;
  1392.      cnop 0,4 ; align for 020+
  1393. level5n:
  1394.      movem.l  d0-d1/a0-a1/a5-a6,-(sp)          ; save registers
  1395.      lea      _custom,a0                  ; get ptr to custom regs
  1396.      move.w   intenar(a0),d1              ; get enabled interrupts
  1397.      and.w      intreqr(a0),d1              ; and in requested interrupts
  1398.      movea.l  SysBase(pc),a6              ; get ExecBase
  1399.      btst      #INTB_DSKSYNC,d1              ; Disk synchronized?
  1400.      beq.b      10$                      ; nope, branch
  1401.      movem.l  IVDSKSYNC(A6),a1/a5              ; get data and code ptrs
  1402.      jsr      (a5)                      ; branch to routine
  1403. 10$     move.l   (sp)+,d0                  ; restore registers
  1404.      move.l   (sp)+,d1                  ; restore registers
  1405.      move.l   (sp)+,a0                  ; restore registers
  1406.      move.l   (sp)+,a1                  ; restore registers
  1407.      move.l   (sp)+,a5                  ; restore registers
  1408.      move.l   (sp)+,a6                  ; restore registers
  1409.      rte                          ; return
  1410.      ;
  1411.      ;      Default Level 5 handler
  1412.      ;
  1413.      ;  a1 - custom chips base
  1414.      ;
  1415.      cnop 0,4 ; align for 020+
  1416. level5:
  1417.      btst      #INTB_INTEN&7,_intenar          ; interrupts enabled?
  1418.      beq.b      45$                      ; nope, ignore
  1419.      btst      #INTB_RBF&7,_intreqr              ; receive buffer full?
  1420.      beq.b      level5n                  ; nope, invoke old handler
  1421.      ;
  1422.      move.l   a0,-(sp)                  ; save registers
  1423.      move.l   a1,-(sp)                  ; save registers
  1424.      lea      _custom,a1                  ; get ptr to custom regs
  1425.      ;
  1426. 10$     tst.b      serdatr(a1)                  ; Overrun?
  1427.      bpl.b      20$                      ; nope, branch
  1428.      ;
  1429.      ;      We've missed some data, so set overrun flag.
  1430.      ;
  1431.      addq.b   #1,Overrun                  ; set overrun flag
  1432. 20$     movea.l  i_BufIn(pc),a0              ; get current ptr
  1433.      move.b   serdatr+1(a1),(a0)+              ; store received byte
  1434.      move.w   #INTF_RBF,intreq(a1)              ; clear RBF interrupt
  1435.      addq.l   #1,i_InCnt                  ; incr bytes in buffer
  1436.      ;
  1437.      cmpa.l   i_BufEnd(pc),a0              ; hit end of buffer?
  1438.      beq.b      60$                      ; yep, branch
  1439. 30$     move.l   a0,i_BufIn                  ; store input ptr
  1440.      ;
  1441.      subq.l   #1,i_Thresh                  ; close to full buffer?
  1442.      beq.b      70$                      ; yep, branch
  1443.      ;
  1444. 40$     btst      #INTB_RBF&7,intreqr(a1)          ; receive buffer full?
  1445.      bne.b      10$                      ; yep, go get another byte
  1446.      ;
  1447.      movea.l  (sp)+,a1                  ; restore registers
  1448.      movea.l  (sp)+,a0                  ; restore registers
  1449. 45$     rte                          ; return
  1450.      ;
  1451.      ;      Hit physical end of buffer, so wrap to the start of the buffer.
  1452.      ;
  1453.      cnop 0,4 ; align for 020+
  1454. 60$     movea.l  i_BufPtr(pc),a0              ; get buffer ptr
  1455.      bra.b      30$                      ; continue
  1456.      ;
  1457.      ;      Hit buffer threshold, so tell other end not to send any more
  1458.      ;      data.
  1459.      ;
  1460.      cnop 0,4 ; align for 020+
  1461. 70$     tst.b      Handshake(pc)               ; are we handshaking?
  1462.      beq.b      40$                      ; nope, skip RTS
  1463.      ori.b      #1<<CIAB_COMRTS,_ciabpra          ; block further input
  1464.      bra.b      40$                      ; go return
  1465.      ;
  1466.      ;
  1467.      ;  a1 - IS_DATA
  1468.      ;  a5 - jump vector register
  1469.      ;
  1470.      cnop 0,4 ; align for 020+
  1471. level2:
  1472.      ;
  1473.      ;      If there's nothing in the buffer, there's no point in going
  1474.      ;      any further.
  1475.      ;
  1476.      tst.l      i_InCnt(pc)                  ; anything in the buffer?
  1477.      bne.b      20$                      ; yep, branch
  1478. 10$     moveq      #0,d0                   ; set Z flag
  1479.      rts                          ; return
  1480.      ;
  1481.      ;      If we've been "disabled" then get out.
  1482.      ;
  1483. 20$     tst.b      disableRead(pc)              ; internally disabled?
  1484.      bge.b      10$                      ; yep, get out of here
  1485.      lea.l      Start(pc),a5                  ; get base
  1486.      ;
  1487.      ;      If we have an active request, branch down and try to fulfill it.
  1488.      ;
  1489.      move.l   cr_IOReq(pc),d0              ; get and test active I/O
  1490.      bne.b      30$                      ; nzero, active, branch
  1491.      ;
  1492.      ;      Get first node in list and test if empty.
  1493.      ;
  1494.      move.l   (a1),a0                  ; get head of list
  1495.      move.l   (a0),d0                  ; get successor
  1496.      beq.b      10$                      ; end of list? yep, branch
  1497.      ;
  1498.      ;      Remove the node from the list
  1499.      ;
  1500.      move.l   d0,(a1)                  ; make new head
  1501.      exg.l      d0,a0                   ; swap nodes
  1502.      move.l   a1,LN_PRED(a0)              ; store predecessor
  1503.      ;
  1504.      ;      Setup fields for processing a read request
  1505.      ;
  1506.      movea.l  d0,a1                   ; get I/O request
  1507.      move.b   IO_FLAGS(a1),d1
  1508.      andi.b   #~(1<<IOSERB_QUEUED),d1          ; no longer queued
  1509.      ori.b      #1<<IOSERB_ACTIVE,d1              ; make it active
  1510.      move.b   d1,IO_FLAGS(a1)
  1511.      move.l   a1,cr_IOReq-Start(a5)           ; store I/O request
  1512.      move.l   IO_DATA(a1),cr_OutPtr-Start(a5)     ; get/set output ptr
  1513.      move.l   IO_LENGTH(a1),cr_Length-Start(a5)   ; get/set output count
  1514.      ;
  1515.      ;      Process an active I/O request
  1516.      ;
  1517. 30$     movea.l  SysBase(pc),a6              ; get ExecBase
  1518.      move.l   d0,a1                   ; get I/O request
  1519.      bsr.b      copyData                  ; go copy 'em
  1520.      tst.l      d0                      ; done with request?
  1521.      beq.b      10$                      ; nope, branch
  1522.      ;
  1523.      ;      the request has been satisfied, so return it.
  1524.      ;
  1525.      clr.l      cr_IOReq-Start(a5)              ; clear request
  1526.      andi.b   #~(1<<IOSERB_ACTIVE),IO_FLAGS(a1)   ; no longer active
  1527.      jsr      _LVOReplyMsg(a6)              ; return I/O
  1528.      bra.b      10$
  1529.      ;
  1530.      ;      Registers:
  1531.      ;      Entry:   A1        Ptr to I/O Request
  1532.      ;           A6        ExecBase
  1533.      ;      Exit:    D0        ZERO - request not done, do not reply it
  1534.      ;                NZERO - request done, reply it
  1535.      ;
  1536.      cnop 0,4 ; align for 020+
  1537. copyData:
  1538.      ;
  1539.      ;      Process an active I/O request (or fall through from above)
  1540.      ;
  1541.      movem.l  d2-d5/a1-a5,-(sp)              ; save registers
  1542.      lea.l      Start(pc),a5                  ; get base
  1543.      movea.l  a1,a4                   ; get I/O request
  1544.      ;
  1545.      movea.l  i_BufOut(pc),a2              ; get current bufout ptr
  1546.      movea.l  cr_OutPtr(pc),a3              ; get current output ptr
  1547.      move.l   cr_Length(pc),d2              ; get current bytes needed
  1548.      move.l   i_InCnt(pc),d3              ; get current bytes in buffer
  1549.     IFNE STATS
  1550.      movem.l  d0-d7/a0-a6,-(sp)
  1551.      lea.l      .stata,a0
  1552.      move.l   d2,.statb
  1553.      lea.l      .statb,a1
  1554.      jsr      KPrintF
  1555.      bra.b      .endstat
  1556. .statb     dc.l      0
  1557.      dc.l      0
  1558. .stata     dc.b      'Length to copy %8ld\n',0
  1559.      cnop      0,4
  1560. .endstat
  1561.      movem.l  (sp)+,d0-d7/a0-a6
  1562.     ENDC
  1563.      ;
  1564.      ;      If we don't have enough bytes to satisfy the request,
  1565.      ;      set the length to the number of bytes we do have.
  1566.      ;
  1567.      cmp.l      d2,d3                   ; enuf to satisfy request?
  1568.      bge.b      15$                      ; yep, so branch
  1569.      move.l   d3,d2                   ; # to copy = # in buffer
  1570.      bra.b      15$                      ; branch to loop entry
  1571.      ;
  1572.      ;      Start of copy loop.
  1573.      ;
  1574.      cnop 0,4 ; align for 020+
  1575. 10$     movea.l  i_BufPtr(pc),a2              ; reset bufout to start
  1576.      ;
  1577.      ;      Entry point of copy loop.
  1578.      ;
  1579. 15$     move.l   d2,d3                   ; xfer # of bytes to copy
  1580.      ;
  1581.      ;      If the copy will extend past the end of the buffer, we can
  1582.      ;      only copy the number of bytes to the end this go around.
  1583.      ;
  1584.      move.l   i_BufEnd(pc),d0              ; get ptr to end of buf
  1585.      sub.l      a2,d0                   ; calc # of bytes to end
  1586.      cmp.l      d0,d3                   ; # to copy < # to end?
  1587.      blt.b      20$                      ; yep, branch
  1588.      move.l   d0,d3                   ; get bytes to end
  1589.      ;
  1590.      ;      Registers:
  1591.      ;
  1592.      ;      A2 = pointer from which data will be copied
  1593.      ;      A3 = pointer to which data will be copied
  1594.      ;      D2 = number of bytes that need to be copied
  1595.      ;      D3 = number of bytes to copy this iteration
  1596.      ;
  1597. 20$     btst      #SERB_EOFMODE,IO_SERFLAGS(a4)       ; EOFMODE requested?
  1598.      beq.b      30$                      ; nope, just go copy
  1599.      ;
  1600.      ;      EOFMODE was specified so copy characters 1 at a time until
  1601.      ;      we hit an EOF character, the output butter has filled, or
  1602.      ;      the input buffer has drained.
  1603.      ;
  1604.      move.l   d3,d0                   ; get length
  1605.      ;
  1606.      lea.l      IO_TERMARRAY+7(a4),a1           ; get termarry ptr
  1607. 21$     move.b   (a2)+,d1                  ; get byte
  1608.      ; This way the term char IS copied (if term char is not copied eofmode will fail)
  1609.      move.b   d1,(a3)+                  ; put in output buffer
  1610.      ;
  1611.      subq.l   #7,a1
  1612.      cmp.b      (a1)+,d1                  ; found term char?
  1613.      bge.b      22$                      ; possibly, branch
  1614.      cmp.b      (a1)+,d1                  ; found term char?
  1615.      bge.b      22$                      ; possibly, branch
  1616.      cmp.b      (a1)+,d1                  ; found term char?
  1617.      bge.b      22$                      ; possibly, branch
  1618.      cmp.b      (a1)+,d1                  ; found term char?
  1619.      bge.b      22$                      ; possibly, branch
  1620.      cmp.b      (a1)+,d1                  ; found term char?
  1621.      bge.b      22$                      ; possibly, branch
  1622.      cmp.b      (a1)+,d1                  ; found term char?
  1623.      bge.b      22$                      ; possibly, branch
  1624.      cmp.b      (a1)+,d1                  ; found term char?
  1625.      bge.b      22$                      ; possibly, branch
  1626.      cmp.b      (a1),d1                  ; found term char?
  1627.      bgt.b      23$                      ; nope, branch
  1628. 22$     beq.b      24$                      ; term char found?
  1629.      ;
  1630.      ;      Didn't find a term character, so continue with the copy loop
  1631.      ;
  1632. 23$
  1633.      subq.l   #1,d0                   ; decr length counter
  1634.      bne.b      21$                      ; continue if more
  1635.      bra.b      40$                      ; done with copy, branch
  1636.      ;
  1637.      ;      We've found a termination character.
  1638.      ;
  1639.      cnop 0,4 ; align for 020+
  1640. 24$     clr.l      cr_Length-Start(a5)              ; done with request
  1641.      bra.b      50$                      ; branch
  1642.      cnop 0,4 ; align for 020+
  1643.      ;
  1644.      ;      EOFMODE not specified, so just do a bulk copy.
  1645.      ;
  1646.      ;      XXX POSSIBLE SPEEDUP XXX
  1647.      ;
  1648.      ;      For short copies it would be quicker to have a simple inline
  1649.      ;      loop, but what's short???  It would be different by CPU.
  1650.      ;
  1651. 30$
  1652.      move.l   d3,d0                   ; get length
  1653.      movea.l  a3,a1                   ; where to put it
  1654.      movea.l  a2,a0                   ; where to get it
  1655. ; NB: buffer size is multiple of 64bytes (not contents size)
  1656. ; most copys are 1 or 2 bytes, max copy usually seen is 256 bytes
  1657.      jsr     _LVOCopyMem(a6)    ; we use copymemquicker patch by *Art
  1658.      adda.l   d3,a2                   ; update bufout
  1659.      adda.l   d3,a3                   ; update outptr
  1660.      ;
  1661.      ;      Fall through and entered from EOFMODE loop
  1662.      ;
  1663.      ;      If the following calculation results in a value greater than
  1664.      ;      zero, then we have a buffer wrap and need to process the
  1665.      ;      remaining bytes at the beginning of the buffer.
  1666.      ;
  1667. 40$     sub.l      d3,d2                   ; calc bytes left to copy
  1668.      bgt      10$                      ; >0, more to copy, branch
  1669.      ;
  1670.      ;
  1671.      ;
  1672. 50$     move.l   a3,d1                   ; get outptr
  1673.      sub.l      cr_OutPtr(pc),d1              ; calc length
  1674.      move.l   a3,cr_OutPtr-Start(a5)          ; update outptr
  1675.      ;
  1676.      ;      Update output ptr and I/O request
  1677.      ;
  1678.      move.l   a2,i_BufOut-Start(a5)           ; store bufout ptr
  1679.      add.l      d1,IO_ACTUAL(a4)              ; update I/O request
  1680.      ;
  1681.      ;      Update number of bytes left in the buffer.
  1682.      ;
  1683.      sub.l      d1,i_InCnt-Start(a5)              ; calc bytes left in buffer
  1684.      ;
  1685.      ;      If the threshold becomes positive here, then, if requested,
  1686.      ;      tell the other end that it's okay to start sending more data.
  1687.      ;
  1688.      add.l      d1,i_Thresh-Start(a5)           ; calc thresh and test
  1689.      ble.b      60$                      ; <= 0, need more data, skip
  1690.      tst.b      Handshake(pc)               ; are we handshaking?
  1691.      beq.b      60$                      ; nope, skip RTS
  1692.      andi.b   #~(1<<CIAB_COMRTS),_ciabpra          ; ready to recieve more data
  1693.      ;
  1694.      ;      Set error if we've had any overruns.
  1695.      ;
  1696. 60$     tst.b      Overrun(pc)                  ; did overrun occur?
  1697.      beq.b      70$                      ; nope, branch
  1698.      clr.b      Overrun-Start(a5)              ; reset overrun flag
  1699.      move.b   #SerErr_LineErr,IO_ERROR(a4)          ; set error code
  1700.      ;
  1701.      ;      Calc number of bytes left to copy.  If the result is greater
  1702.      ;      than zero, then we have more to copy so return an incomplete
  1703.      ;      status.
  1704.      ;
  1705. 70$     moveq      #0,d0                   ; assume I/O incomplete
  1706.      sub.l      d1,cr_Length-Start(a5)          ; update length and test
  1707.      bgt.b      90$                      ; >0, more to do, branch
  1708.      ;
  1709.      ;      We've completed the I/O request either by copying the requested
  1710.      ;      of bytes or by finding an EOFMODE character, so return a "reply"
  1711.      ;      status.
  1712.      ;
  1713.      moveq      #1,d0                   ; indicate reply
  1714.      ;
  1715.      ;      Restore and exit
  1716.      ;
  1717. 90$     move.l   (sp)+,d2                  ; restore registers
  1718.      move.l   (sp)+,d3                  ; restore registers
  1719.      move.l   (sp)+,d4                  ; restore registers
  1720.      move.l   (sp)+,d5                  ; restore registers
  1721.      move.l   (sp)+,a1                  ; restore registers
  1722.      move.l   (sp)+,a2                  ; restore registers
  1723.      move.l   (sp)+,a3                  ; restore registers
  1724.      move.l   (sp)+,a4                  ; restore registers
  1725.      move.l   (sp)+,a5                  ; restore registers
  1726.      rts                          ; return (status in D0)
  1727.      ;
  1728.      ;      Align data
  1729.      ;
  1730.      CNOP      0,4
  1731.      ;
  1732.      ;
  1733.      ;
  1734. Init:
  1735.      DC.L      sizeof_Base8n1
  1736.      DC.L      funcTab
  1737.      DC.L      dataTab
  1738.      DC.L      InitRoutine
  1739.      ;
  1740.      ;
  1741.      ;
  1742. funcTab:
  1743.      DC.W      -1
  1744.      DC.W      dev_Open-funcTab
  1745.      DC.W      dev_Close-funcTab
  1746.      DC.W      dev_Expunge-funcTab
  1747.      DC.W      dev_Null-funcTab
  1748.      DC.W      dev_BeginIO-funcTab
  1749.      DC.W      dev_AbortIO-funcTab
  1750.      DC.W      -1
  1751.      ;
  1752.      ;
  1753.      ;
  1754. dataTab:
  1755.      INITBYTE LN_TYPE,NT_DEVICE
  1756.      INITLONG LN_NAME,Name
  1757.      INITBYTE LIB_FLAGS,LIBF_SUMUSED|LIBF_CHANGED
  1758.      INITWORD LIB_VERSION,VERSION
  1759.      INITWORD LIB_REVISION,REVISION
  1760.      INITLONG LIB_IDSTRING,IdString
  1761.      DC.W      0
  1762.      ;
  1763.      ;      String Constants
  1764.      ;
  1765. miscresource:
  1766.      DC.B      "misc.resource",0
  1767. timerdevice:
  1768.      DC.B      "timer.device",0
  1769. intuitlib:
  1770.      DC.B      "intuition.library",0
  1771. Name:
  1772.      DC.B      "8n1.device",0
  1773. IdString:
  1774.      VSTRING
  1775.      ;
  1776.      ;      End of checksummed area.  (Realigns data too!)
  1777.      ;
  1778. ENDTag:
  1779.      CNOP      0,4
  1780.      ;
  1781.      ;      Global SysBase (Use instead of _AbsExecBase for speed)
  1782.      ;
  1783. SysBase:
  1784.      DC.L      0
  1785.      ;
  1786.      ;      Internal buffer tracking (DO NOT CHANGE THE ORDER!!!!)
  1787.      ;
  1788. i_BufPtr:
  1789.      DC.L      0
  1790. i_BufIn:
  1791.      DC.L      0
  1792. i_BufOut:
  1793.      DC.L      0
  1794. i_BufEnd:
  1795.      DC.L      0
  1796. i_InCnt:
  1797.      DC.L      0
  1798. i_Thresh:
  1799.      DC.L      0
  1800.      ;
  1801.      ;      Used while processing a read request.
  1802.      ;
  1803. cr_IOReq:
  1804.      DC.L      0
  1805. cr_OutPtr:
  1806.      DC.L      0
  1807. cr_Length:
  1808.      DC.L      0
  1809.      ;
  1810.      ;      List head for read requests
  1811.      ;
  1812. readQ:
  1813.      DC.L      readQ+MLH_TAIL
  1814.      DC.L      0
  1815.      DC.L      readQ
  1816.      ;
  1817.      ;      Write control.
  1818.      ;
  1819. cw_Length:
  1820.      DC.L      0
  1821. cw_Buffer:
  1822.      DC.L      0
  1823. cw_IOReq:
  1824.      DC.L      0
  1825.      ;
  1826.      ;      List head for write requests
  1827.      ;
  1828. writeQ:
  1829.      DC.L      writeQ+MLH_TAIL
  1830.      DC.L      0
  1831.      DC.L      writeQ
  1832.      ;
  1833.      ;
  1834.      ;
  1835. timerPort:
  1836.      DC.L      0                      ; LN_SUCC
  1837.      DC.L      0                      ; LN_PRED
  1838.      DC.B      NT_MSGPORT                  ; LN_TYPE
  1839.      DC.B      0                      ; LN_PRI
  1840.      DC.L      0                      ; LN_NAME
  1841.      DC.B      3                      ; MP_FLAGS (undoc'ed)
  1842.      DC.B      0                      ; MP_SIGBIT
  1843.      DC.L      timerRtn                  ; MP_SIGTASK
  1844.      DC.L      timerPort+MP_MSGLIST+LH_TAIL          ; LH_HEAD
  1845.      DC.L      0                      ; LH_TAIL
  1846.      DC.L      timerPort+MP_MSGLIST              ; LH_TAILPRED
  1847.      DC.B      0                      ; LH_TYPE
  1848.      DC.B      0                      ; LH_pad
  1849.      DC.W      0                      ; long align
  1850.      ;
  1851.      ;
  1852.      ;
  1853. timerReq:
  1854.      DC.L      0                      ; LN_SUCC
  1855.      DC.L      0                      ; LN_PRED
  1856.      DC.B      NT_MESSAGE                  ; LN_TYPE
  1857.      DC.B      0                      ; LN_PRI
  1858.      DC.L      0                      ; LN_NAME
  1859.      DC.L      timerPort                  ; MN_REPLYPORT
  1860.      DC.W      IOTV_SIZE                  ; MN_LENGTH
  1861.      DC.L      0                      ; IO_DEVICE
  1862.      DC.L      0                      ; IO_UNIT
  1863.      DC.W      TR_ADDREQUEST               ; IO_COMMAND
  1864.      DC.B      0                      ; IO_FLAGS
  1865.      DC.B      0                      ; IO_ERROR
  1866.      DC.L      0                      ; TV_SECS
  1867.      DC.L      0                      ; TV_MICROS
  1868.      ;
  1869.      ;
  1870.      ;
  1871. VBInterrupt:
  1872.      DC.L      0                      ; LN_SUCC
  1873.      DC.L      0                      ; LN_PRED
  1874.      DC.B      NT_INTERRUPT                  ; LN_TYPE
  1875.      DC.B      0                      ; LN_PRI
  1876.      DC.L      Name                      ; LN_NAME
  1877.      DC.L      readQ                   ; IS_DATA
  1878.      DC.L      level2                  ; IS_CODE
  1879.      ;
  1880.      ;      Global flags
  1881.      ;
  1882. Overrun:
  1883.      DC.B      0
  1884. Handshake:
  1885.      DC.B      1
  1886. disableRead:
  1887.      DC.B      -1
  1888.      CNOP      0,4
  1889. cmdlist:
  1890.      dc.w      CMD_RESET
  1891.      dc.w      CMD_READ
  1892.      dc.w      CMD_WRITE
  1893.      dc.w      CMD_CLEAR
  1894.      dc.w      CMD_FLUSH
  1895.      dc.w      SDCMD_QUERY
  1896.      dc.w      SDCMD_BREAK
  1897.      dc.w      SDCMD_SETPARAMS
  1898.      dc.w      NSCMD_DEVICEQUERY
  1899.      dc.w      0
  1900.      ;
  1901.      ;
  1902.      ;
  1903.      END
  1904.  
  1905.